Значение свойства объекта может быть присвоено вручную через окно свойств или программно

lblVivod.Caption=“Вывод данных”

7.Событие представляет собой действие, распознаваемое объектом (например, щелчок мышью или нажатие клавиши), для которого можно запрограммировать отклик. События возникают в результате действий пользователя или программы, или же они могут быть вызваны системой.

Событие	Действие
Click	Щелчок мышкой
MouseDown	Нажатие клавиши мыши
MouseMove	Перемещение мыши

Например: cmdExit_Click

2 этап Работа с готовыми программами

Пример программы:

Процесс программирования состоит из 2 частей:

· визуальное конструирование;

· программирование событий;

Программа-приветствие

1.

2.

Private Sub cmdExit_Click()

End

End Sub

Private Sub txtInput_Change()

lblOutput.Caption = "Здравствуй, " & txtInput.Text & "!"

End Sub

Программа-перевод курса валют

Private Sub cmdExit_Click()

End

End Sub

Private Sub cmdPerevod_Click()

lblRezult.Caption = "Результат - " & txtKurs.Text * txtNal.Text & " руб."

End Sub

3 этап Составление программ

Самостоятельное составление программ и решение задач.

5.Методика введения понятия «Графические методы»

1 этап Подготовительный

1.Метод представляет собой действие, выполняемое над объектом. Графические методы используются для построения изображений на поверхности объектов.

Формат команды: объект.метод (например, frmMyForm.cls).

2.Графические методы применимы к следующим объектам: форма (Form) и картинка (PictureBox).

3.Система координат. 1 см = 567 твипов. Свойства: Left (координаты левой границы), Top (координата верхней границы), Width (ширина), Height (высота).

Свойство ScaleMode отвечает за единицу измерения (ScaleWidth, ScaleHeight).

4.Основные методы:

· CLS – очищает поверхность объекта;

· PSET [STEP] (X,Y) [, Цвет] – точка;

цвет может быть задан функцией RGB(255,255,255);

Step — ключевое слово, обозначающее, что начальная или конечная координата линии задана относительно текущей позиции, задаваемой свойствами CurrentX и CurrentY (отсчитывается как смещение от текущей позиции);

· POINT (X,Y) – цвет точки;

· LINE [STEP] (X1,Y1) – [STEP] (X2,Y2) [,Цвет] – линия;

· LINE [STEP] (X1,Y1) – [STEP] (X2,Y2) [,Цвет], B – прямоугольник;

· LINE [STEP] (X1,Y1) – [STEP] (X2,Y2) [,Цвет], BF – закрашенный прямоугольник;

· CIRCLE [STEP] (X,Y), Radius [, Цвет] – окружность;

· CIRCLE [STEP] (X,Y), Radius [, Цвет],,,Koefficient – эллипс;

· CIRCLE [STEP] (X,Y), Radius [, Цвет], Start, End, Koefficient – дуга;

· CIRCLE [STEP] (X,Y), Radius [, Цвет], -Start, -End, Koefficient – сектор;

5.Значения по умолчанию:

· ForeColor – цвет изображения;

· BackColor – цвет фона;

· DrawWidth – толщина линии в пикселях (по умолчанию 1);

· DrawStyle – тип линии (по умолчанию сплошная);

· FillColor – цвет закраски фигуры;

· FillStyle – способ закраски фигуры;

2 этап Работа с готовыми программами

Пример программы:

Процесс программирования состоит из 2 частей:

· визуальное конструирование;

· программирование событий;

Программа-пейзаж

Private Sub cmdCLS_Click()

picPeisag.Cls

End Sub

Private Sub cmdExit_Click()

End

End Sub

Private Sub cmdPusk_Click()

picPeisag.Line (0, 70)-(picPeisag.ScaleWidth, 70), vbGreen

picPeisag.Circle (20, 15), 10, vbYellow

picPeisag.Line (60, 70)-(90, 40), vbBlue, B

picPeisag.Line -(75, 20), vbBlue

picPeisag.Line -(60, 40), vbBlue

picPeisag.PSet (70, 50), vbRed

picPeisag.Line -(80, 60), vbRed, B

End Sub

3 этап Составление программ

Самостоятельное составление программ и решение задач.

6.Методика введения понятия “Процедуры”

1 этап Подготовительный

1.Процедуры бывают событийными и общими. Общие процедуры бывают общедоступными (глобальными) и местными (локальными).

Public Sub Name (Arguments) Общедоступная процедура [Exit Sub] End Sub
Вызов процедуры – Name Arguments
Private Sub Name (Arguments) Локальная процедура в форме [Exit Sub] End Sub
Если перед именем переменной поставить команду ByVal, то параметр передается по значению, а не по ссылке.

2.Аргументы

Команда Option Explicit принуждает пользователя к обязательному объявлению всех переменных и аргументов.

Объявление переменных: Dim Name1 As Tip1, Name2 As Tip2

2 этап Работа с готовыми программами

Пример программы:

Процесс программирования состоит из 2 частей:

· визуальное конструирование;

· программирование событий;

Проект Домики: вывести на объект PictureBox 3 подобных домика.

Option Explicit

Private Sub cmdClear_Click()

picDom.Cls

End Sub

Private Sub cmdExit_Click()

End

End Sub

Private Sub cmdPusk_Click()

Dim Color As Long

Color = RGB(255, 0, 0)

picDom.PSet (10, 30), Color

Domik 15, 20, Color

Color = RGB(0, 255, 0)

picDom.PSet (50, 60), Color

Domik 20, 25, Color

Color = RGB(0, 0, 255)

picDom.PSet (80, 50), Color

Domik 30, 30, Color

End Sub

Sub Prymoug(a As Long, b As Long, c As Long)

picDom.Line Step(0, 0)-Step(a, -b), c, B

End Sub

Sub Treug(a As Long, h As Long, c As Long)

picDom.Line Step(0, 0)-Step(a, 0), c

picDom.Line -Step(-a / 2, -h), c

picDom.Line -Step(-a / 2, h), c

End Sub

Sub Domik(a As Long, h As Long, c As Long)

Prymoug a, 2 * h / 3, c

picDom.PSet Step(-a, 0), c

Treug a, h / 3, c

picDom.Circle Step(a / 2, -h / 7), h / 10, c

End Sub

3 этап Составление программ

Самостоятельное составление программ и решение задач.

7.Методика введения понятия “Функции”

1 этап Подготовительный

1.Функции бывают общедоступными (глобальными) и местными (локальными).

Public Function Name (Arguments) As Tip Общедоступная функция [Exit Function] Name=Rezult End Function	Private Function Name (Arguments) As Tip Локальная функция в форме [Exit Function] Name=Rezult End Function
Если перед именем переменной поставить команду ByVal, то параметр передается по значению, а не по ссылке.
Вызов функции – Peremennay=NameFunction(Arguments)

2.Аргументы

Команда Option Explicit принуждает пользователя к обязательному объявлению всех переменных и аргументов.

Объявление переменных: Dim Name1 As Tip1, Name2 As Tip2

2 этап Работа с готовыми программами

Пример программы:

Программа расчета объема цилиндра и конуса.

Модуль Obiom.bas

Public Function Ploshad(Radius As Double) As Double

Const PI = 3.1415

Ploshad = PI * Radius ^ 2

End Function

MDI форма frmMDIMain

Private Sub mnuExit_Click()

End

End Sub

Private Sub mnuKonus_Click()

frmKonus.Show

End Sub

Private Sub mnuCilindr_Click()

frmCilindr.Show

End Sub

Дочерняя форма frmKonus

Свойство MDIChild=True

Private Sub cmdExit_Click()

Unload Me

End Sub

Private Sub cmdRaschet_Click()

lblObiom = "Объем = " & Ploshad(txtRadius.Text) * txtVisota.Text/3

End Sub

Дочерняя форма frmCilindr

Private Sub cmdExit_Click()

Unload Me

End Sub

Private Sub cmdRaschet_Click()

lblObiom = "Объем = " & Ploshad(txtRadius.Text) * txtVisota.Text

End Sub

3 этап Составление программ

Самостоятельное составление программ и решение задач.

8.Методика введения понятия “Команда выбора IF”

1 этап Подготовительный

1.Команды выбора предназначены для управления ходом выполнения программы.

2.Команды выбора организуются следующими операторами:

Сокращенная форма If условие Then оператор Полная форма If условие Then оператор1 Else оператор2

Полная блочная форма If условие Then блок1 Else блок2 End If

3.Логические функции:

AND – И;

OR – ИЛИ;

NOT – НЕ;

И

A	B	Результат

ИЛИ

A	B	Результат

НЕ

A	Результат

Условие при A=5
=	A=5	равно	Истинно
< >	A< >5	не равно	Ложно
<	A<5	меньше	Ложно
>	A>5	больше	Ложно
<=	A<=5	меньше или равно	Истинно
>=	A>=5	больше или равно	Истинно

Логические операции

OR	(A>2) OR (A>8)	ИЛИ	Истинно
AND	(A>2) AND (A>8)	логическое И	Ложно
NOT	NOT(A>8)	отрицание	Истинно

2 этап Работа с готовыми программами

Пример программы:

Проект Поиск Y по X

Option Explicit

Dim X As Double, Y As Variant

Private Sub cmdExit_Click()

End

End Sub

Private Sub cmdRschet_Click()

X = Val(txtX.Text)

If X <= 10 And X <> 5 Then

Y = 1 / (X - 5)

Else

If X > 15 Then

Y = Cos(X)

Else

Y = "не определено"

End If

End If

lblY.Caption = “Y=” & Y

End Sub

3 этап Составление программ

Самостоятельное составление программ и решение задач.

9.Методика введения понятия “Команда выбора CASE”

1 этап Подготовительный

1.Команды выбора предназначены для управления ходом выполнения программы.

2.Команды выбора организуются следующими операторами:

Select Case X Case X1 блок1 Case X2 to X3 блок2 Case Is > X4 блок3 Case Else блок4 End Select

Оценивается значение переменой X:

- 1 значение;

- диапазон от X2 до X3;

- условие.

3.Условия применимости команд выбора:

Команда Case применяется при множественном выборе по одному параметру. Во всех остальных случаях применяется команда IF.

2 этап Работа с готовыми программами

Пример программы:

Проект Простой графический редактор

Private Sub cmdClear_Click()

picGrRed.Cls

End Sub

Private Sub cmdExit_Click()

End

End Sub

Private Sub picGrRed_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)

picGrRed.CurrentX = X

picGrRed.CurrentY = Y

End Sub

Private Sub picGrRed_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)

Select Case Button

Case 1

picGrRed.Line -(X, Y), vbRed

Case 2

picGrRed.Line -(X, Y), vbYellow

Case 4

picGrRed.Line -(X, Y), vbGreen

Case Else

End Select

End Sub

3 этап Составление программ

Самостоятельное составление программ и решение задач.

10.Методика введения понятия “Элемент управления CheckBox”

1 этап Подготовительный

1.Элементы управления предназначены для предоставления пользователю возможности управления ходом работы программы.

2. Элементы управления представлены следующими объектами:

CheckBox Value – значения True и False Возможен множественный выбор.

2 этап Работа с готовыми программами

Пример программы:

frmCheck

Проект «Форматирование текста»

cmdClose

chkItalic

chkBold

txtDisplay

Private Sub chkBold_Click()

If ChkBold.Value Then

txtDisplay.FontBold = True

Else

txtDisplay.FontBold = False

End If

End Sub

Private Sub chkItalic_Click()

txtDisplay.FontItalic =ChkItalic.Value

End Sub

Private Sub cmdClose_Click()

End

End Sub

3 этап Составление программ

Самостоятельное составление программ и решение задач.

11.Методика введения понятия “Элементы управления OptionButton”

1 этап Подготовительный

1.Элементы управления предназначены для предоставления пользователю возможности управления ходом работы программы.

2. Элементы управления представлены следующими объектами:

OptionButton Value – значения True и False Возможно выбрать только один вариант из множества.

2 этап Работа с готовыми программами

Пример программы:

Проект Простая обучающая программа по английскому языку

Private Sub cmdExit_Click()

End

End Sub

Private Sub optZveri_Click(Index As Integer)

ImgMain.Picture = imgRis(Index). Picture

End Sub

3 этап Составление программ

Самостоятельное составление программ и решение задач.

12.Методика введения понятия “Полосы прокрутки”

1 этап Подготовительный

1.Полосы прокрутки предназначены для изменения значений.

2. Полосы прокрутки представлены следующими объектами:

HscrollBar - горизонтальная Value – значение Min и Max – пределы изменения

VscrollBar - вертикальная Value – значение Min и Max – пределы изменения

2 этап Работа с готовыми программами

Пример программы:

Проект Смешивание цветов

Private Sub cmdClose_Click()

End 'Закрытие формы.

End Sub

Private Sub DoColor() 'Процедура окраски текстового окна

txtColor.BackColor = RGB(hsbRed.Value, hsbGreen.Value, hsbBlue.Value)

End Sub

Private Sub hsbBlue_Change() 'Процедура обработки события "Изменение"

hsbBlue_Scroll 'Вызов процедуры перемещение ползунка.

End Sub

Private Sub hsbBlue_Scroll() 'Процедура обработки события "Перемещение ползунка"

DoColor 'Вызов главной процедуры окраски окна

End Sub

Private Sub hsbGreen_Change()

hsbGreen_Scroll

End Sub

Private Sub hsbGreen_Scroll()

DoColor

End Sub

Private Sub hsbRed_Change()

hsbRed_Scroll

End Sub

Private Sub hsbRed_Scroll()

DoColor

End Sub

3 этап Составление программ

Самостоятельное составление программ и решение задач.

13.Методика введения понятия “Цикл FOR”

1 этап Подготовительный

1.Циклы применяются для повторения нескольких шагов множество раз.

2. Циклы организуются следующими операторами:

For K=Nach to Kon Step Shag команды [Exit For] Next K

3.Условия применимости циклов:

Цикл For применяется в том случае, когда известны начало, конец, шаг или количество повторений цикла.

2 этап Работа с готовыми программами

Пример программы:

Проект «Улица»

Option Explicit

Private Sub cmdCLS_Click()

picUlica.Cls

End Sub

Private Sub cmdExit_Click()

End

End Sub

Sub Prymoug(a As Long, b As Long, c As Long)

picUlica.Line Step(0, 0)-Step(a, -b), c, B

End Sub

Sub Treug(a As Long, h As Long, c As Long)

picUlica.Line Step(0, 0)-Step(a, 0), c

picUlica.Line -Step(-a / 2, -h), c

picUlica.Line -Step(-a / 2, h), c

End Sub

Sub Domik(a As Long, h As Long, c As Long)

Prymoug a, 2 * h / 3, c

picUlica.PSet Step(-a, 0), c

Treug a, h / 3, c

picUlica.Circle Step(a / 2, -h / 7), h / 10, c

End Sub

Private Sub cmdDraw_Click()

Dim Color As Long, Dom As Integer

picUlica.FillStyle = vbSolid

For Dom = 0 To picUlica.ScaleWidth Step 10

Color = RGB(Rnd(Date) * 255, Rnd(Date) * 255, Rnd(Date) * 255)

picUlica.FillColor = Color

picUlica.PSet (Dom, 60), Color

Domik 15, 15, Color

Next Dom

End Sub

3 этап Составление программ

Самостоятельное составление программ и решение задач.

14.Методика введения понятия “Цикл WHILE”

1 этап Подготовительный

1.Циклы применяются для повторения нескольких шагов множество раз.

2. Циклы организуются следующими операторами:

Do While условие выполняется команды [Exit Do] Loop	Do команды [Exit Do] Loop While условие выполняется
Do Until условие не выполняется команды [Exit Do] Loop	Do команды [Exit Do] Loop Until условие не выполняется

3.Условия применимости циклов:

Цикл While (Until) применяется когда известно условие выхода из цикла.

2 этап Работа с готовыми программами

Пример программы:

Проект «Пирамида»

Option Explicit

Private Sub cmdDraw_Click()

Dim SOsn As Single, Shag As Single, X0 As Single, Y0 As Single, Dlina As Single

picPiramid.Cls

X0 = picPiramid.ScaleWidth / 2

Y0 = picPiramid.ScaleHeight / 2

SOsn = Val(txtOsn.Text)

Shag = Val(txtShag.Text)

Dlina = Sqr(SOsn)

picPiramid.FillStyle = vbSolid

Do

picPiramid.FillColor = RGB(Rnd(Date) * 255, Rnd(Date) * 255, Rnd(Date) * 255)

picPiramid.Line (X0 - Dlina / 2, Y0 - Dlina / 2)-Step(Dlina, Dlina),, B

Dlina = Dlina - Shag

Loop While Dlina > 0

End Sub

Private Sub cmdExit_Click()

End

End Sub

3 этап Составление программ

Самостоятельное составление программ и решение задач.

15.Методика введения понятия “Графические объекты”

1 этап Подготовительный

1.Графические объекты предназначены для вывода и редактирования изображения.

2. Графические объекты представлены следующими объектами:

Image (образ) Picture – свойство, отвечающее за изображение Имеет свойство Stretch (растянуть образ до размера объекта) Применяется для отображения изображений	PictureBox (картинка) Picture – свойство, отвечающее за изображение Имеет свойство AutoSize (автоматическое изменение размера объекта под размер картинки) Применяется для рисования
Line (линия) Координаты X1, Y1, X2, Y2 BorderColor - цвет BorderStyle - стиль BorderWidth - толщина	Shape (фигура) Свойство Shape: 0 – прямоугольник 1 – квадрат 2 – овал 3 - окружность

2 этап Работа с готовыми программами

Пример программы:

1.Проект Цилиндр

Private Sub Form_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)

If X >= linLObr.X1 And X <= linLObr.X2 And Y >= linLObr.Y1 And Y <= linLObr.Y2 Then

lblLObr.Visible = True

linLObr.BorderColor = &HFF&

Else

lblLObr.Visible = False

linLObr.BorderColor = &H0&

End If

If X >= shpVOsn.Left And X <= shpVOsn.Left + shpVOsn.Width And Y >= shpVOsn.Top And Y <= shpVOsn.Top + shpVOsn.Height Then

lblVOsn.Visible = True

shpVOsn.FillStyle = 0

Else

lblVOsn.Visible = False

shpVOsn.FillStyle = 1

End If

If X >= linPObr.X1 And X <= linPObr.X2 And Y >= linPObr.Y1 And Y <= linPObr.Y2 Then

lblPObr.Visible = True

linPObr.BorderColor = &HFF&

Else

lblPObr.Visible = False

linPObr.BorderColor = &H0&

End If

If X >= shpNOsn.Left And X <= shpNOsn.Left + shpNOsn.Width And Y >= shpNOsn.Top And Y <= shpNOsn.Top + shpNOsn.Height Then

lblNOsn.Visible = True

shpNOsn.FillStyle = 0

Else

lblNOsn.Visible = False

shpNOsn.FillStyle = 1

End If

End Sub

Private Sub lblPrym_Click()

MsgBox "Прямоугольник - это параллелограмм, у которого все углы прямые.", 32, Title:="Прямоугольник"

End Sub

Private Sub mnuExit_Click()

End

End Sub

3 этап Составление программ

Самостоятельное составление программ и решение задач.

16.Методика введения понятия “Символьные величины”.

1 этап Подготовительный

1.Символьные величины предназначены для хранения набора символов. Символьная величина представляет собой таблицу. Объявление строковой переменной:
Dim Stroka As String
Stroka= “информатика”

2.Для работы со строковой переменной используются следующие функции:

Len(Stroka) – длина строки;

Simvol=Mid(Stroka,Nachalo, Dlina) – вырезка из переменной;

Mid(Stroka,Nachalo, Dlina)= Simvol – замена части символов;

Right(Stroka, Dlina) – вырезка с правой стороны строки;

Left(Stroka, Dlina) – вырезка с левой стороны строки;

Chr$(Cod) – символ по коду (Chr$(10)+Chr$(13));

Asc(Symbol) – код символа;

2 этап Работа с готовыми программами

Пример программы: