2015-04-23
2275
Можно упростить любой из существующих языков программирования до уровня, удобного для изучения основных методов разработки компиляторов. Такой подход используется достаточно часто. Он удобен и позволяет легко разобрать различные методы построения компиляторов. Назовем разрабатываемый язык DPL (Demonstration Programming Language).
Синтаксис и семантика DPL. DPL содержит основные операторы обработки данных и управления, которые позволяют строить простые программы. Вместе с тем, в нем отсутствуют конструкции, широко применяемые в развитых языках. В частности, нет процедур и функций, блочной структуры, пользовательских типов данных, классов. Описание языка строится по традиционному принципу. В начале будут рассмотрены элементарные конструкции, а затем структура программы.
Элементарные конструкции. К элементарным конструкциям языка обычно относятся его понятия, состоящие из терминальных символов, принадлежащих алфавиту языка.
К элементарным относятся такие понятия, как идентификатор, числа (целые, действительные, двоичные, десятичные), комментарии, метки, знаки операций, разделители, строки символов. Список можно продолжить и дальше. Эти понятия уточняются и конкретизируются при описании семантики языка. Например, идентификатор может служить в качестве имени переменной, процедуры, функции или типа.
|
|
|
Ниже приводится синтаксис элементарных конструкций DPL. Их описанию предшествует определение групп основных символов в качестве отдельных понятий, разделяющих эти символы на отдельные категории (классы).
$ буква = "A"|"B"|"C"|"D"|"E"|"F"|"G"|"H"|"I"|"J"|"K"|"L"|"M"|"N"| "O"|"P"|"Q"|"R" |"S"|"T"|"U"|"V"|"W"|"X"|"Y"|"Z"|"a"|"b"|"c"|"d"|"e"|"f"|"g"|"h"|"i"|"j"|"k"|"l"|"m"|"n"|"o"|"p"|"q"|"r"|"s"|"t"|"u"|"v"|"w"|"x"|"y"|"z".
$ цифра = "0"|"1"|"2"|"3"|"4"|"5"|"6"|"7"|"8"|"9".
$ идентификатор = (буква | "_") { буква | цифра | "_" }.
$ число = целое | действительное.
$ целое = двоичное | восьмиричное | десятичное |
шестнадцатиричное.
$ двоичное = "{2}" {/ "0" | "1" /}.
$ восьмиричное = "{8}"{ "0"|"1"|"2"|"3"|"4"|"5"|"6"|"7" }.
$ десятичное = ["{10}"] {/ цифра /}.
$ шестнадцатиричное = "{16}" {/ цифра |"A"|"B"|"C"|"D"|"E"|"F"|
"a"|"b"|"c"|"d"|"e"|"f" /}.
$ действительное = числовая_строка порядок | числовая_строка
"." [числовая_строка] [порядок] | "." числовая_строка [порядок].
|
|
|
$ числовая_строка = {/ цифра /}.
$ порядок = ("E"|"e")["+"|"-"] числовая_строка.
$ пробельный_символ = {/ пробел | табуляция | перевод_строки |
комментарий /}.
$ комментарий = "/*" { символ } "*/".
$ строка = """ { символ | """"} """.
Дополнительным описанием следует также снабдить понятия комментария и строки. Комментарий может задаваться в любом месте программы, где можно поставить пробел или разделитель. Он начинается парой символов "/*" и заканчивается другой парой "*/". Между ними могут быть любые печатаемые символы, включая отдельные группы звездочек и наклонных линий, не образующих завершающую комбинацию, а также символы табуляции, перевода строки. Строка может содержать только видимые символы, заключенные между двумя кавычками. Если в строке необходимо поставить кавычку, то она дублируется при написании:
"Строка, в которой следующее ""слово"" взято в кавычки".
Ключевые слова и разделители используются для формирования выражений, описаний и операторов. В DPL они определяются следующим образом:
$ ключевое_слово = abort | begin | case | end | float | goto | int | loop |
or | read | skip | space | tab | var | write |.
$ разделитель = "(" | ")" | "[" | "]" | "," | ";" | ":" | ":=" | "*" | "/" | "%" |
"+" | "-" | "->" |"<" | "=" | ">" | "<=" | ">=" | "!=".
Составные конструкции. Организация программы. К составным конструкциям относятся понятия, определяющие структуру программы, ее операторов, описаний и выражений:
$ программа = begin (описание | оператор)
{ ";" (описание | оператор) } end.
$ описание = var идентификатор [ размер ]
{ "," идентификатор [ размер ] } ":" тип.
$ тип = int | float.
$ размер = целое.
$ оператор = метка непомеченный.
$ метка = идентификатор ":".
$ непомеченный = присваивания | условный | цикла | пустой |
ошибки | ввода | вывода | перехода.
$ присваивания = переменная ":=" выражение |
переменная "," присваивания "," выражение.
$ переменная = идентификатор [ "[" выражение "]" ].
$ выражение = [ "-" ] операнд { операция [ "-" ] операнд }.
$ операнд = "(" выражение ")" | число | переменная.
$ операция = "*" | "/" | "%" | "+" | "-" | "<" | "=" | ">" | ">=" |
"<=" | "!=".
$ условный = case [ набор_ резервируемых ] end.
$ цикла = loop [ набор_ резервируемых ] end.
$ набор_резервируемых = резервируемые [ or резервируемые ].
$ резервируемые = выражение "->" оператор { ";" оператор }.
$ пустой = skip |.
$ прерывания = abort [строка].
$ ввода = read переменная { "," переменная }.
$ вывода = write (выражение | спецификатор | строка)
{ "," (выражение | спецификатор | строка) }.
$ перехода = goto идентификатор.
$ спецификатор = (space | tab | skip) [ выражение ].
Приведенные правила требуют некоторых дополнительных пояснений, раскрывающих особенности семантики языка.
Краткое описание семантики языка. Оператор присваивания имеет нетрадиционную форму и, в общем случае, обеспечивает одновременное присваивание нескольким переменным, расположенным слева от знака «:=» значений предварительно вычисленных выражений, расположенных в правой части. Каждой переменной соответствует свое выражение. Присваивания начинаются только после вычисления всех выражений, результаты которых временно сохраняются. Это позволяет произвести обмен значений переменных с использованием только одного оператора присваивания:
x, y:= y, x
В обычных языках программирования необходимо написать три отдельных оператора:
t:= x; x:= y; y:= t
Выражения задаются в традиционной инфиксной форме. Порядок выполнения операций определяется их приоритетом и скобками. В начале выполняются выражения в скобках. Наивысший приоритет имеет унарный минус «-», далее следуют мультипликативные операции «*», «/», «%» (вычисление остатка), затем аддитивные «+», «-» и, наконец операции отношения «<», «=», «>», «<=», «>=», «!=».
|
|
|
Для экстренного выхода из любой точки программы в языке используется оператор прерывания abort. Необязательная строка символов предназначена для пояснения причины выхода из программы.
В соответствии с концепциями безошибочного программирования, разработанными Дейкстрой, определены условный оператор и оператор цикла. Их тела содержат наборы операторов, выполнение которых возможно только при истинности условий, задаваемых предваряющими их охраняющими выражениями. Выражения отделяются от зарезервированных ими операторов стрелками «->» и, начиная с первого, последовательно анализируются до тех пор, пока не встретится «истинное». Истинным считается ненулевое значение выражения. Предполагается, что в рассматриваемой версии языка операции отношения возвращают в качестве результата целое число, равное 1, при выполнении условия и, равное 0, если условие не выполняется. Если в условном операторе все охраняющие выражения дают ложь, то он выполняется как оператор ошибки (abort). Оператор цикла в данной ситуации эквивалентен пустому оператору (skip). Возникновение такой ситуации обеспечивает выход из цикла. При наличии истинного охраняющего выражения происходит выполнение охраняемых операторов и повторное выполнение оператора цикла. Оператор abort также эквивалентен конструкции case end (пустое тело в условном операторе), а оператор skip - оператору loop end.
Спецификаторы space, tab и skip используются в операторе вывода для форматирования выходного потока данных и означают пробел, табуляцию и перевод строки. Выражение, следующее за спецификатором, определяет количество его повторений. Строка символов используется для вывода пояснительного текста.
