Расчет простого резистивного делителя
Рис. 52. Схема с пронумерованными узлами
Описание схемы для программы SPICE, файл circ1.cir, первая строка - заголовок:
Расчет резистивного делителя по постоянному току
R1 1 2 10
R2 2 0 5
V1 1 0 10V
.OP
.END
Пусть теперь необходимо для этой схемы рассчитать зависимость напряжения во 2 узле при изменении напряжения питания V1 от 0 до 50 Вольт с шагом 1В. Результаты необходимо вывести в файл для постпроцессора PROBE. В этом случае входной файл circ11.cir запишется:
Расчет резистивного делителя по постоянному току
R1 1 2 10
R2 2 0 5
V1 1 0 10V
.DC V1 0V 50V 1V
.PRINT DC V(1) V(2)
.PROBE
.END
Расчет частотной хаpактеристики простой RC-цепочки
Источник Е1 имеет синусоидальную форму сигнала, амплитуду 10 Вольт и частоту, изменяющуюся от 100Гц до 10МГц.
Рис. 55. Схема с пронумерованными узлами
Описание схемы для программы SPICE (файл circ1.cir):
Расчет RC-цепочки на синусоидальном сигнале
R1 1 2 10
С1 2 0 5UF
V1 1 0 AC 10V SIN(0 10V 1k)
.AC DEC 50 100 10MEG
.PLOT AC V(2)
.END
Анализ схемы включения транзистора с общим эмиттером
|
|
Расчет частотной характеристики схемы с ОЭ (рис. 54). Файл с описанием схемы:
Рис. 54. Схема с пронумерованными узлами
Исследование схемы включения транзистора с ОЭ
R1 4 2 53k
R2 2 0 10k
R3 4 3 5k
R4 5 0 1k
RL 6 0 10k
C1 1 2 20UF
C2 3 6 20UF
C3 5 0 100UF
Q1 4 2 5 KT315
.model KT315 NPN(Is=1.e-13 Bf=50)
Vc 4 0 10V
Vin 1 0 DC 0V AC 0.02V SIN(0V 0.02V 1kHZ)
* расчет рабочей точки схемы
.OP
* расчет частотной характеристики
.AC DEC 5 10Hz 100kHz
.PROBE
.END
Расчет ключа на биполярном транзисторе. (передаточная характеристика)
Файл с описанием схемы (рис. 55):
Ключ на биполярном транзисторе
R1 1 2 1k
Rk 4 3 1k
Vsupl 4 0 5V
Q1 3 2 0 kt317
.model KT317 NPN(Is=1.e-13 Bf=200 Br=5 Vaf=74 Var=30
+ Rb=230 Rc=15 Re=2 Cje=1pF Cjc=3pF Tf=12.e-9 Tr=7.e-8)
Vin 1 0 0V
* Расчет передаточной характеристики
* Входное напряжение меняется от 0 до 5 В с шагом 0.1 В
.DC Vin 0 5 0.1
.PROBE
.end
Рис. 55. Схема с пронумерованными узлами
Расчет ключа на биполярном транзисторе. (переходная характеристика, рис. 55)
Ключ на биполярном транзисторе
R1 1 2 1k
Rk 4 3 1k
Vsupl 4 0 5V
Q1 3 2 0 kt317
.model KT317 NPN(Is=1.e-13 Bf=200 Br=5 Vaf=74 Var=30
+ Rb=230 Rc=15 Re=2
+ Cje=1pF Cjc=3pF Tf=12.e-9 Tr=7.e-8)
Vin 1 0 PULSE(0V 5V 1us 10ns 10ns 100us 200us)
* расчет переходной характеристики, шаг вывода по времени 0.3 мкс,
* время моделирования 180 мкс
.TRAN 0.3us 180us
.PROBE
.end
Расчет выходных характеристик биполярного транзистора (лабораторная работа № 1)
Рис. 56. Схема с пронумерованными узлами
Файл с описанием схемы:
Биполярный транзистор
Ib 0 1 30u
Vc 2 0 5V
Q1 2 1 0 kt317
.model KT317 NPN(Is=1.e-13 Bf=200 Br=5 Vaf=74 Var=30
+ Rb=230 Rc=15 Re=2 Cje=1pF Cjc=3pF Tf=12.e-9 Tr=7.e-8)
* Расчет выходных характеристик
* Ток базы принимает значения 30, 50, 70 мкА,
* Коллекторное напряжение меняется от 0 до 5 В с шагом 0.1 В
.DC Vc 0 5 0.1 Ib 30u 70u 20u
.PROBE
.end
Расчет входных характеристик биполярного транзистора
|
|
Рис. 57. Схема с пронумерованными узлами
Файл с описанием схемы:
Биполярный транзистор
Vb 1 0 0.8V
Vc 2 0 3V
Q1 2 1 0 kt317
.model KT317 NPN(Is=1.e-13 Bf=200 Br=5 Vaf=74 Var=30
+ Rb=230 Rc=15 Re=2 Cje=1pF Cjc=3pF Tf=12.e-9 Tr=7.e-8)
* Расчет входных характеристик
* Напряжение базы меняется от 0 до 0.8 В с шагом 0.01 В
* Коллекторное напряжение равно 3В
.DC Vb 0 0.8 0.01
.PROBE
.end